ЭлементыФормы.Найти (Controls.Find)

ЭлементыФормы (Controls)

Найти (Find)

Доступен, начиная с версии 8.0.

Синтаксис:

Найти(<Наименование>)

Параметры:

<Наименование> (обязательный)

Тип: Строка.
Наименование элемента формы.

Возвращаемое значение:

Тип: Элемент управления формы, Неопределено.
Элемент управления в форме. Если элемент не найден, то возвращается значение Неопределено.

Описание:

Осуществляет поиск элемента управления с заданным именем.

Доступность:

Толстый клиент.

Пример:

Процедура АктивизироватьРеквизитВФорме(ФормаДокумента) Экспорт
    // Структура - порядок активизации реквизитов.

    // Активизируется первый не заполненный.

    СтруктураРеквизитов = Новый Структура;

    СтруктураРеквизитов.Вставить("Дата");
    СтруктураРеквизитов.Вставить("Номер");
    СтруктураРеквизитов.Вставить("Организация");
    СтруктураРеквизитов.Вставить("Касса");
    СтруктураРеквизитов.Вставить("БанковскийСчет");
    СтруктураРеквизитов.Вставить("Склад");
    СтруктураРеквизитов.Вставить("Контрагент");
    СтруктураРеквизитов.Вставить("Получатель");
    СтруктураРеквизитов.Вставить("Плательщик");
    СтруктураРеквизитов.Вставить("ФизЛицо");

    Для каждого Элемент Из СтруктураРеквизитов Цикл
        // Определим, есть ли ЭУ с таким именем.

        ЭУ = ФормаДокумента.ЭлементыФормы.Найти(Элемент.Ключ);
        Если ЭУ  <> Неопределено Тогда
            // есть такой элемент

            Если Не ЗначениеЗаполнено(ЭУ.Значение) Тогда
                // Нашли не заполненный ЭУ.

                // Делаем его текущим и прекращаем цикл.

                ФормаДокумента.ТекущийЭлемент = ЭУ;
                Прервать;
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
КонецПроцедуры

Использование в версии:

Доступен, начиная с версии 8.0.

Методическая информация